FreeRTOS integration (Alpha)

RoomModel minihil.selftest.RtosTask {

	import etrice.api.types.*
	import etrice.api.timer.PTimer
	import etrice.api.logger.PLogger

	ExternalType SemaphoreHandle_t -> "SemaphoreHandle_t" default "NULL"

	ActorClass AActorWithRtosTask {
		Interface {
		}
		Structure {
			usercode1 '''
				#include "FreeRTOS.h"
				#include "task.h"
				#include "semphr.h"
			'''

			SAP timer: PTimer
			SAP logger: PLogger

			Attribute taskSemaphore: SemaphoreHandle_t
			Attribute counter: uint16 = "0"
		}
		Behavior {
			Operation theRtosTask() '''
				while(1) {
					// wait indefinitly for semaphore
					xSemaphoreTake(taskSemaphore, portMAX_DELAY);
					counter++;
				}
			'''
			StateMachine {
				State wait {
					entry '''timer.startTimeout(100);'''
				}
				State active
				Transition init0: initial -> wait
				Transition tr0: wait -> active {
					triggers {
						<timeout: timer>
					}
					action '''
						// create semaphore for task signaling
						taskSemaphore = xSemaphoreCreateBinary();
						xSemaphoreGive(taskSemaphore);
						// start task. As its prio is higher than the etrice tasks prio it will run immediately
						BaseType_t xReturn;
						xReturn = xTaskCreate((void (*)(void *))AActorWithRtosTask_theRtosTask, "actorTask", configMINIMAL_STACK_SIZE, self, 4 | portPRIVILEGE_BIT, NULL);
						// the following lines will be called once the task yields/changes to unready state (e.g. by waiting for a semaphore).
						if (xReturn == pdPASS && NULL != taskSemaphore) {
						    // task successfully created
						}


						timer.startTimer(300);'''
				}
				Transition tr1: active -> active {
					triggers {
						<timeout: timer>
					}
					action '''
						logger.logF("Count: %d", counter);
						xSemaphoreGive(taskSemaphore);
					'''
				}
			}
		}
	}
}